'/******************************************************************
'*******************************************************************
'Programme qui appelles l'utilitaire de back-up de voute et permet de spécifier un nombre de back-up a conserver.
'Entreé : Aucune entrée requise
'Modifier les paramètres ci-bas pour fitter avec vos besoins
'Fait par Jean-Michel Dufour, le 28 septembre 2005 a Trois-Riviere
'Modifié par Eric Paris le 07 mai 2007
'support@irisco.com
'*******************************************************************
'******************************************************************/







RepBackUp = "c:\VaultBackup"
	'Specifier le repertoire de back-up. S'assurer qu'il existe !!!


BackToKeep = 2
	'Nombre de back-up a conserver.


FichierLog ="c:\VaultBackup\BackupLog.txt"
	'Repertoire de log des back-up.


AdminUser = "administrator"
	'User qui a les privilèges administrateur sur le serveur de voute pour faire le back-up


AdminPassword = "password"
	'Mot de passe du user ci-haut mentionné. Si pas de mot de passe laissé "aucun"


RepInstallation = "C:\Program Files\Autodesk\Data Management Server 2008\ADMS Console\Connectivity.ADMSConsole.exe"
	'Repertoire ou le serveur de voute est installé.






'*******************************************************************
'*******************************************************************
'	CODE PROPREMENT DIT, NE PAS MODIFIER SVP
'*******************************************************************
'*******************************************************************





Set fso = CreateObject("Scripting.FileSystemObject")
Set f = fso.GetFolder(RepBackUp) ' Si rep existe pas, le script va planté ce qui nous force a le créer avant d'aller plus loin

set WshShell = CreateObject("WScript.Shell")

tmp = WshShell.Run("iisreset /stop",2,True)

if AdminPassword = "aucun" then
	tmp = WshShell.Run(Chr(34) & RepInstallation & Chr(34) & " -S -Obackup -B" & RepBackUp & " -VU" & AdminUser & " -L" & FichierLog,2,True)
else
	tmp = WshShell.Run(Chr(34) & RepInstallation & Chr(34) & " -S -Obackup -B" & RepBackUp & " -VU" & AdminUser & " -VP" & AdminPassword & " -L" & FichierLog,2,True)
end if

tmp = WshShell.Run("iisreset /start",2,True)


Set sf = f.SubFolders
if sf.Count > BackToKeep then 'Effacer le plus vieux

	Ecart = 0
	For Each SousDossier in sf
		
		Difference = DateDiff("n", Now, SousDossier.DateCreated)
		if Difference < Ecart then
			OlderName = SousDossier.Name
			Ecart = Difference
		end if
	Next
	Set FolderEffacer = fso.GetFolder(RepBackUp & "\" & OlderName)
	FolderEffacer.delete

end if

'Si vous faites modifs quand meme, m'envoyer la source pour que je le distribue aux autres personnes